Audiodateien vervielfachen und zählend benennen

[Nikut]

Hallo!

Ich suche ein Programm, mit dem ich ein Audiofile kopieren und dann unter einem neuen Dateinamen abspeichern kann. Das sollte alles automatisch geschehen, sodass ich nur sagen muss, von wann bis wann das Programm Kopien erstellen muss.
So brauche ich Audiofiles mit dem Dateinamen 00001 bis 04204, die alle erstellt werden müssen.

Hat jemand von euch eine Ahnung, wie man das am besten hinbekommt?

[Nikut]

Ok.. das Programm "Flash Renamer" konnte mir beim Dateinamen ändern helfen. Alles andere (die Anzahl der Dateien) hat Strg+C und Strg+V für mich geregelt.
Puh.. was man nicht alles für den Seminarkurs tut.

[RAT:]

OK, zu spät ... aber fürs nächste Mal:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
IF (%1)==() GOTO HELP
IF (%2)==() GOTO HELP

:START
SET /a end=%2
SET src=%1
SET ext=%src:~-3%
FOR /L %%c in (1, 1, %end%) do set "out=000%%c" &set "out=!out:~-4!" &call :cpy
ECHO Fertig, %end% Dateien erstellt
GOTO ENDE

:CPY
COPY %src% %out%.%ext% > NUL
ECHO %src% nach %out%.%ext% kopiert
GOTO :EOF

:HELP
ECHO.
ECHO Aufruf: %0 Dateiname Anzahl (1 bis 9999)
ECHO.
ECHO Beispiel: %0 Quelldatei.txt 2048
ECHO.
ECHO Kopiert die Datei "Quelldatei.txt" 2048 mal nach 0001.txt bis 2048.txt
ECHO Die Dateinamen sind 4-stellig mit fuehrenden Nullen. Fuer andere
ECHO Notationen oder Erweiterung ueber 9999 ist der Quelltext anzupassen
ECHO.
GOTO ENDE

:ENDE
ECHO.

Datei als <irgendetwas>.cmd abspeichern und ausführen.

[Nikut]

Das funktioniert, wenn ich das richtig sehe bei aller Art von Dateien?
Die Anzahl lässt sich auch variieren?

[RAT:]

Ja, genau.
Ab Windows 7 funktioniert es sicher, bei Vista und XP weiß ich nicht, ob die Kommandozeilenerweiterungen schon implementiert sind. Außerdem funktioniert es so z.Zt. nur, wenn die Dateinamenserweiterung 3 Zeichen lang ist (=> SET ext=%src:~-3% = die letzten 3 Zeichen). Mit set "out=000%%c" &set "out=!out:~-4!" wird die temporäre Variable %out% als String auf 000 + Zähler gesetzt, also zB auf 0001 für 1 und auf 0009999 für 9999, dann werden die letzten 4 Stellen genommen, also 0001 oder 9999. Mit diesem Kniff erreicht man, dass die Dateinamen mit führenden Nullen geschrieben werden.

Was man als Quelldatei nimmt ist Wurscht - nur die Erweiterung sollte eben 3-stellig sein (txt, wav, mp3, jpg, doc, xls ... egal). Für z.B. docx oder xlsx müßte man SET ext=%src:~-3% ändern auf SET ext=%src:~-4%.

[Nikut]

Danke RAT:!
Jetzt ist nicht nur mir in Zukunft, sondern auch anderne Forenusern geholfen

[colabiert]

heftig!

Wie funktioniert das jetzt? Wo trage ich im code meine Datei ein? Kommt der Pfad meiner Datei dann bei 'quelldatei.txt' rein, oder wie?

[RAT:]

Das Ding ist 'nen Kommandozeilenskript und erwartet die Angaben als Parameter.

Windows bis XP: Start/Ausführen, cmd eingeben und mit Enter bestätigen
Windows 7: Start, "Programme/Dateien durchsuchen", cmd eingeben und die vorgeschlagene cmd.exe ausführen
Windows 8: Keine Ahnung^^

Windows 7 Beispiel:





Bei dem Beispiel springe ich in mein Desktop-Verzeichnis (Verzeichniswechsel mit CD), erstelle einen neuen Ordner (MD), kopiere meine als Multicopy.cmd auf Laufwerk F: gespeicherte Datei dort hinein, hole mir dazu eine beliebige andere Datei und starte die als mcpy.cmd kopierte Skriptdatei. Schön sieht man da auch die Beschränkung auf 3 Zeichen für die Dateierweiterung, an die ich Trottel nicht gedacht habe. So sind aus meiner .html-Datei nun .tml-Dateien entstanden^^

[colabiert]

ich versteh nur bahnhof. schade - ich dachte man kopiert das in eine editor datei rein und speichert die als cmd .____.

[RAT:]

ich versteh nur bahnhof. schade - ich dachte man kopiert das in eine editor datei rein und speichert die als cmd .____.

Ja, genau so. Ich habe nur das "danach" etwas ausführlicher beschrieben, da ich dachte cmd+bat kennt nicht mehr jeder. Als powershell-script wollte ich das nicht machen, obwohl man da einfacher zB an die Länge der Dateiendung kommt (kennt ja immerhin das FileInfo-Objekt), aber da .ps standardmäßig deaktiviert ist, hab ich mir das verkniffen.