Wasteland Warrior - Diskussionen, Kritik, Anregungen #2

[Boïndil]

Habe die Feuerameisen alle ein wenig runtergeschraubt und die schwereren kommen jetzt später.

Sieht jetzt besser aus mit der Ghul-Verwandlung, habe verschiedene Effekte und Animationen eingebaut.
Jetzt zickt das im Hardcore-Modus aber noch mit den Fraktionen, das ist ein schier undurchschaubares Geflecht, das es einem schwierig macht, das einem wirklich alle hassen. Okay, muss den Player per Script aus drei verschiedenen Fraktionen rauswerfen und ihn nach der Verwandlung wieder hinzufügen, damit das mit der Brotherhood klappt. Wieso ich aber die Arefu-Fraktion nicht feindlich kriege, ist mir ein Rätsel. Mache es gleich wie in Megaton und Big Town und die ballern auf mich los, was das Zeug hält.

Edit
Ist übrigens ziemlich mühsam, Bethesda scheint sämtliche Online-Dokumentationen für Oblivion, Fallout 3, NV und sogar Skyrim deaktiviert zu haben, wenn man Infos braucht, ist man jetzt aufgeschmissen.

War den halben Tag an diesem Script am rumschrauben, das sämtliche RAD-Effekte, die Gift-Halluzinationen und die Ghulverwandlung steuert.
Das mit der Umstellung der Fraktionen ist besonders heikel, ich kann nicht einfach Fraktionen dumm an- und ausschalten oder von Freund auf Feind umschalten, wenn ich die ursprünglichen Reaktionen wieder haben möchte. Ich muss teilweise auslesen, welche Fraktionen dem Player während dem Spiel hinzugefügt wurden, oder mit wem er es sich verscherzt hat. Wenn man die Bomben auf die Citadel fallen lässt, wird auch Cross feindlich und auch in Paradise Falls, Pitt oder Lookout muss ich die ursprünglichen Beziehungen wieder ehrstellen. Musste gar manches Script oder Quest-Stage genauer ansehen, damit ich keinen Scheiss code. Habe da jetzt alles nochmals überarbeitet, vertieft und neu durchdacht. Hoffentlich sind endlich alle feindlich, die es sein sollten und wieder friedlich, wenn es vorbei ist.

Wer es sich ansehen möchte:

scn wlwQuestIntoxicationScript

Spoiler:

; Bedingungen in Messages definieren
short DoOnce
short ResetIt
short FollowerCount
short FollowerMax
short ResetTimer
short CanUseGrenade
short ButtonPressed
short RadMsgOnce
short GhoulWpnOnce
short IsStartMsg
short DoOnce
; Vergleich zu wlwQuest.RadMode
short RadMode
; Variablen Gift
float PoisonTimer
short PoisonApplied
; Variablen Rad
float RadTimer
short RadState
short RandomFactor
short RadFxApplied
short ApplyRadLevel
; Variablen Ghulifizierung
short IsGhoul
short GhoulFxTimer
short ApplyGhoulFx
short ApplyGhoulSound
short RemoveGhoulForm
short ApplyGhoulLevel
short GhulQuestRunning
short EffectsDisabled
short CanRecruitGhoul
short DismissTimer
short WasCannibal
short KarmaLevel
short BrotherhoodMember
short BrotherhoodAlly
short ReillyMember
short OutcastAlly

Begin GameMode

    ; Einmaliger Start oder Update
    If DoOnce < 2
        Set RadMode To wlwQuest.RadMode
        Set DoOnce To 2
    EndIf

    ; Ghul-Status ermitteln
    If GhulQuestRunning == 0 && IsGhoul > 0
        Set FollowerMax To 3
        Set FollowerCount To 0
        Set ResetTimer To 1
        DLC04FF02DunwichObeliskREF.enable
        If wlwQuest.RadMode == 3
            SetObjectiveDisplayed wlwQuestGhoulHeal 20 1
        Else
            SetObjectiveDisplayed wlwQuestGhoulHeal 10 1
        EndIf
        Set GhulQuestRunning To 1
    EndIf    

    ; Start-Message Rads
    If RadMsgOnce == 0 && Player.GetAv RadiationRads > 400
        Set wlwQuestFunction.ShowMsg To 1
        Set RadMsgOnce To 1
    EndIf

    ; Gift-Halluzinationen (im Survivor-Modus und nicht als Ghul)
    If wlwQuest.ModeSurvivor == 1 && IsGhoul == 0
        If Player.HasMagicEffect wlwPoisonBaseEffect
            If  PoisonTimer > 50
                RiMod wlwEffectPoisonHalluzination
                If GetRandomPercent > 50 && Player.GetHealthPercentage > 0.25
                    PlaySound VOCRadioGhouls
                    IMod wlwEffectPoisonHalluzination
                EndIf
                Set PoisonApplied To 1
                Set PoisonTimer To 0
            Else
                Set PoisonTimer To PoisonTimer + GetSecondsPassed
            EndIf
        Else
            If PoisonApplied == 1
                RiMod wlwEffectPoisonHalluzination
                Set PoisonApplied To 0
            EndIf
        EndIf
    EndIf
    
    ; Radiation-Effekte
    If RadMode == wlwQuest.RadMode
        If Player.GetAv RadiationRads > 800
            If RadState == 0 && IsGhoul == 0
                wlwPlayerMatchHumanRef.MatchRace Player
                Set KarmaLevel To Player.GetAv Karma
            EndIf
            If RadState != 2
                If RadMode == 1
                    Set ApplyRadLevel To 2
                ElseIf RadMode > 1 && IsGhoul != 2
                    Set ApplyGhoulLevel To 2
                EndIf
                Set RadState To 2
            EndIf
        ElseIf Player.GetAv RadiationRads > 600
            If RadState == 0 && IsGhoul == 0
                wlwPlayerMatchHumanRef.MatchRace Player
                Set KarmaLevel To Player.GetAv Karma
            EndIf
            If RadState != 1
                If RadMode == 1
                    Set ApplyRadLevel To 1
                ElseIf RadMode == 2
                    Set ApplyGhoulLevel To 1
                ElseIf RadMode == 3 && IsGhoul == 0
                    Set ApplyGhoulLevel To 1
                EndIf                
                Set RadState To 1
            EndIf
        Else
            If RadState != 0
                If RadMode < 2
                    Set ApplyRadLevel To -1
                ElseIf RadMode == 2
                    Set ApplyGhoulLevel To -1
                EndIf
                Set RadState To 0
            EndIf
        EndIf
    Else
        ; Player hat Modus im Menu geaendert, zuerst nullen, dann wieder beginnen
        Set RadMode To wlwQuest.RadMode
        ; Abgleich mit Variable
        If RadState > 0
            Set RadState To 0
            Set ApplyGhoulLevel To -1
            Set ApplyRadLevel To -1
        EndIf
    EndIf
    
    ; Ghul-Level anpassen
    If ApplyGhoulLevel != 0 && wlwQuestFunction.ApplyGhoulFx == 0
        Set wlwQuestFunction.ApplyGhoulFx To ApplyGhoulLevel
        Set GhoulFxTimer To 1
    EndIf
    If GhoulFxTimer > 0
        Set GhoulFxTimer To GhoulFxTimer - 1
    ElseIf ApplyGhoulLevel == 1 ; Effekte Level 1
        Set IsGhoul To 1
        Set CanRecruitGhoul To 0
        Set FollowerCount To 0
        Set wlwPerkGhoulFleshChance To 100
        Player.RemoveFromFaction wlwTypePlayerGhoulFaction2
        Player.AddToFaction wlwTypePlayerGhoulFaction1 1
        Player.MatchRace wlwPlayerMatchGhoul1Ref
        Player.RemoveSpell wlwPlayerGhoulSpell2
        Player.AddSpell wlwPlayerGhoulSpell1
        Player.RemoveItem wlwWpnGhoulGrenade 20 1
        Player.RemoveItem wlwWpnFeralGhoulClaws 1 1
        SetEnemy PlayerFaction FeralGhoulFaction
        Player.RemoveFromFaction FeralGhoulFaction
        If WasCannibal == 0
            Player.RemovePerk Cannibal
        EndIf
        Set ApplyGhoulLevel To 0
    ElseIf ApplyGhoulLevel == 2  ; Effekte Level 2
        Set IsGhoul To 2
        Set FollowerCount To 0
        Set DismissTimer To 1
        Set wlwPerkGhoulFleshChance To 10
        Player.RemoveFromFaction wlwTypePlayerGhoulFaction1
        Player.AddToFaction wlwTypePlayerGhoulFaction2 1
        Player.MatchRace wlwPlayerMatchGhoul2Ref
        Player.RemoveSpell wlwPlayerGhoulSpell1
        Player.AddSpell wlwPlayerGhoulSpell2
        Player.AddItem wlwWpnGhoulGrenade 3
        Player.AddItem wlwWpnFeralGhoulClaws 1
        Player.AddItem HumanFlesh 9 1
        ClearFactionPlayerEnemyFlag FeralGhoulFaction
        SetAlly PlayerFaction FeralGhoulFaction 1 1
        If WasCannibal == 0
            Player.AddPerk Cannibal
        EndIf
        If RadMode == 3
            ; Karma
            RewardKarma -2000
            ; Ghul-Fraktion
            Player.AddToFaction FeralGhoulFaction 1
            ; Gruppen
            SetEnemy PlayerFaction MS13CanMez
            SetEnemy PlayerFaction SmokerFaction
            SetEnemy PlayerFaction GeneralIdleFaction
            SetEnemy PlayerFaction WastelanderFaction            
            SetEnemy PlayerFaction WastelandScavengerFaction
            SetEnemy PlayerFaction WastelandHunterFaction
            SetEnemy PlayerFaction TraderFaction            
            SetEnemy PlayerFaction SlaverFaction
            SetEnemy PlayerFaction SlaveFaction            
            ; Siedlungen
            SetEnemy PlayerFaction ArefuFaction
            SetEnemy PlayerFaction BigTownFaction
            SetEnemy PlayerFaction CantCommonsFaction
            SetEnemy PlayerFaction GirdershadeFaction
            SetEnemy PlayerFaction LamplightResidentFaction
            SetEnemy PlayerFaction MegatonSettlerFaction
            SetEnemy PlayerFaction ParadiseFallsResidentFaction
            SetEnemy PlayerFaction RCResidentFaction
            SetEnemy PlayerFaction TennpennyResidentFaction
            ; Spezielle Gruppen
            SetEnemy PlayerFaction ParadiseFallsSlaverFaction
            If Player.GetInFaction ReillysRangersFaction
                Set ReillyMember To 1
                Player.RemoveFromFaction ReillysRangersFaction
            EndIf
            SetEnemy PlayerFaction ReillysRangersFaction
            If Player.GetInFaction BrotherhoodSteelFaction
                Set BrotherhoodMember To 1
                Player.RemoveFromFaction BrotherhoodSteelFaction
            EndIf
            SetEnemy PlayerFaction BrotherhoodSteelFaction
            If Player.GetInFaction MQPlayerBOSAllyFaction
                Set BrotherhoodAlly To 1
                Player.RemoveFromFaction MQPlayerBOSAllyFaction
            EndIf        
            Player.RemoveFromFaction MQ01BrotherhoodDCFaction
            If Player.GetInFaction BrotherhoodOutcastAllyFaction
                Set OutcastAlly To 1
                Player.RemoveFromFaction BrotherhoodOutcastAllyFaction
            EndIf                
            SetEnemy PlayerFaction BrotherhoodOutcastFaction            
            ; DLC-Gruppen
            SetEnemy PlayerFaction DLC01PittRaiderFaction
            SetEnemy PlayerFaction DLC01PittSlaveFaction
            SetEnemy PlayerFaction DLC04TribalFriendlyFaction    
            ; Begleiter
            SetEnemy PlayerFaction wlwFollowerFactionButch
            SetEnemy PlayerFaction wlwFollowerFactionCharon
            SetEnemy PlayerFaction wlwFollowerFactionClover
            SetEnemy PlayerFaction wlwFollowerFactionCross
            SetEnemy PlayerFaction wlwFollowerFactionFawkes
            SetEnemy PlayerFaction wlwFollowerFactionJericho
            SetEnemy PlayerFaction wlwFollowerFactionRL3
            SetEnemy PlayerFaction wlwFollowerFactionDogmeat
        EndIf
        If GhoulWpnOnce == 0
            Set GhoulWpnOnce To 1
            ShowMessage wlwInfoGhoulWeapons
        EndIf
        Set ApplyGhoulLevel To 0
    ElseIf ApplyGhoulLevel == -1 ; Effekte entfernen
        Set IsGhoul To 0
        Set CanRecruitGhoul To 0
        Set FollowerCount To 0
        Set wlwPerkGhoulFleshChance To 100
        Player.RemoveFromFaction wlwTypePlayerGhoulFaction1
        Player.RemoveFromFaction wlwTypePlayerGhoulFaction2
        Player.RemoveSpell wlwPlayerGhoulSpell1
        Player.RemoveSpell wlwPlayerGhoulSpell2
        Player.MatchRace wlwPlayerMatchHumanRef
        ; WTF!!!!
        Player.agerace -9
        Player.agerace 1
        Player.RemoveItem wlwWpnGhoulGrenade 20 1
        Player.RemoveItem wlwWpnFeralGhoulClaws 1 1
        Player.RemoveFromFaction FeralGhoulFaction
        SetEnemy PlayerFaction FeralGhoulFaction
        If WasCannibal == 0
            Player.RemovePerk Cannibal
        EndIf
        If RadMode == 3
            ; Karma    neutral    
            RewardKarma 1000
            ; Gruppen            
            SetEnemy PlayerFaction MS13CanMez 1 1
            SetEnemy PlayerFaction SmokerFaction 1 1
            SetEnemy PlayerFaction GeneralIdleFaction 1 1
            SetEnemy PlayerFaction WastelanderFaction 1 1            
            SetEnemy PlayerFaction WastelandScavengerFaction 1 1
            SetEnemy PlayerFaction WastelandHunterFaction 1 1
            SetEnemy PlayerFaction TraderFaction 1 1        
            SetEnemy PlayerFaction SlaverFaction 1 1
            SetEnemy PlayerFaction SlaveFaction 1 1    
            ClearFactionPlayerEnemyFlag MS13CanMez
            ClearFactionPlayerEnemyFlag SmokerFaction
            ClearFactionPlayerEnemyFlag GeneralIdleFaction
            ClearFactionPlayerEnemyFlag WastelanderFaction            
            ClearFactionPlayerEnemyFlag WastelandScavengerFaction
            ClearFactionPlayerEnemyFlag WastelandHunterFaction
            ClearFactionPlayerEnemyFlag TraderFaction        
            ClearFactionPlayerEnemyFlag SlaverFaction
            ClearFactionPlayerEnemyFlag SlaveFaction            
            ; Siedlungen
            If MS09ArefuHates == 0
                SetEnemy PlayerFaction ArefuFaction 1 1
            EndIf
            SetEnemy PlayerFaction BigTownFaction 1 1
            SetEnemy PlayerFaction CantCommonsFaction 1 1
            SetEnemy PlayerFaction GirdershadeFaction 1 1
            SetEnemy PlayerFaction LamplightResidentFaction 1 1
            SetEnemy PlayerFaction MegatonSettlerFaction 1 1
            SetEnemy PlayerFaction ParadiseFallsResidentFaction 1 1
            SetEnemy PlayerFaction RCResidentFaction 1 1
            SetEnemy PlayerFaction TennpennyResidentFaction 1 1
            ClearFactionPlayerEnemyFlag BigTownFaction
            ClearFactionPlayerEnemyFlag CantCommonsFaction
            ClearFactionPlayerEnemyFlag GirdershadeFaction
            ClearFactionPlayerEnemyFlag LamplightResidentFaction
            ClearFactionPlayerEnemyFlag MegatonSettlerFaction
            ClearFactionPlayerEnemyFlag ParadiseFallsResidentFaction
            ClearFactionPlayerEnemyFlag RCResidentFaction
            ClearFactionPlayerEnemyFlag TennpennyResidentFaction
            ; Spezielle Gruppen
            If wlwQuestAmbush.ParadiseSlaversPissed == 0
                SetEnemy PlayerFaction ParadiseFallsSlaverFaction 1 1
            EndIf
            If ReillyMember == 1
                Set ReillyMember To 0
                Player.AddToFaction ReillysRangersFaction 1
            EndIf
            SetEnemy PlayerFaction ReillysRangersFaction 1 1
            If wlwQuestAmbush.BrotherhoodPissed == 0
                If BrotherhoodMember == 1
                    Set BrotherhoodMember To 0
                    Player.AddToFaction BrotherhoodSteelFaction 1
                EndIf
                SetEnemy PlayerFaction BrotherhoodSteelFaction 1 1
                If BrotherhoodAlly == 1
                    Set BrotherhoodAlly To 0
                    Player.AddToFaction MQPlayerBOSAllyFaction 1
                EndIf        
                Player.AddToFaction MQ01BrotherhoodDCFaction 1
                SetEnemy PlayerFaction BrotherhoodSteelFaction 1 1
                ClearFactionPlayerEnemyFlag BrotherhoodSteelFaction                
                SetEnemy PlayerFaction wlwFollowerFactionCross 1 1
                ClearFactionPlayerEnemyFlag wlwFollowerFactionCross
            EndIf
            If wlwQuestAmbush.OutcastPissed == 0
                If OutcastAlly == 1
                    Set OutcastAlly To 0
                    Player.AddToFaction BrotherhoodOutcastAllyFaction 1
                EndIf                
                SetEnemy PlayerFaction BrotherhoodOutcastFaction 1 1
                ClearFactionPlayerEnemyFlag BrotherhoodOutcastFaction
            EndIf
            ; DLC-Gruppen
            If wlwQuestAmbush.PittRaiderPissed == 0            
                SetEnemy PlayerFaction DLC01PittRaiderFaction 1 1
                ClearFactionPlayerEnemyFlag DLC01PittRaiderFaction            
            EndIf    
            If wlwQuestAmbush.PittSlavesPissed == 0            
                SetEnemy PlayerFaction DLC01PittSlaveFaction 1 1
                ClearFactionPlayerEnemyFlag DLC01PittSlaveFaction            
            EndIf    
            If wlwQuestAmbush.TribalsPissed == 0            
                SetEnemy PlayerFaction DLC04TribalFriendlyFaction 1 1
                ClearFactionPlayerEnemyFlag DLC04TribalFriendlyFaction            
            EndIf            
            ; Begleiter
            SetEnemy PlayerFaction wlwFollowerFactionButch 1 1
            SetEnemy PlayerFaction wlwFollowerFactionCharon 1 1
            SetEnemy PlayerFaction wlwFollowerFactionClover 1 1
            SetEnemy PlayerFaction wlwFollowerFactionFawkes 1 1
            SetEnemy PlayerFaction wlwFollowerFactionJericho 1 1
            SetEnemy PlayerFaction wlwFollowerFactionRL3 1 1
            SetEnemy PlayerFaction wlwFollowerFactionDogmeat 1 1            
            ClearFactionPlayerEnemyFlag wlwFollowerFactionButch
            ClearFactionPlayerEnemyFlag wlwFollowerFactionCharon
            ClearFactionPlayerEnemyFlag wlwFollowerFactionClover
            ClearFactionPlayerEnemyFlag wlwFollowerFactionFawkes
            ClearFactionPlayerEnemyFlag wlwFollowerFactionJericho
            ClearFactionPlayerEnemyFlag wlwFollowerFactionRL3
            ClearFactionPlayerEnemyFlag wlwFollowerFactionDogmeat
        EndIf
        If GhulQuestRunning == 1
            SetObjectiveCompleted wlwQuestGhoulHeal 20 1
            SetObjectiveCompleted wlwQuestGhoulHeal 10 1
            CompleteQuest  wlwQuestGhoulHeal
            Set GhulQuestRunning To 0
        EndIf
        Set RadMode To wlwQuest.RadMode
        Set ApplyGhoulLevel To 0
    EndIf

    ; Effekt anwenden: RAD-Halluzinationen
    If ApplyRadLevel == 1 ; Effekte Level 1
        IMod wlwEffectRad1
        RiMod wlwEffectRad2
        Set ApplyRadLevel To 0
    ElseIf ApplyRadLevel == 2 ; Effekte Level 2
        IMod wlwEffectRad2
        RiMod wlwEffectRad1
        Set ApplyRadLevel To 0
    ElseIf ApplyRadLevel == -1 ; Effekte entfernen
        RIMod wlwEffectRad1
        RIMod wlwEffectRad2
        RIMod wlwEffectRad1Halluzination
        RIMod wlwEffectRad2Halluzination
        Set ApplyRadLevel To 0
    EndIf

    ; Sporadische RAD-Effekte
    If RadState > 0 && RadMode == 1
        If RadTimer > 30
            If RadFxApplied == 1
                RIMod wlwEffectRad1Halluzination
                RIMod wlwEffectRad2Halluzination
                Set RadFxApplied To 0
            EndIf
            If GetRandomPercent < (RadState * 30)
                Set RadFxApplied To 1
                If RadState == 1
                    IMod wlwEffectRad1Halluzination
                ElseIf RadState == 2
                    IMod wlwEffectRad2Halluzination
                EndIf
                SetRumble 0.1 0.1 7
                If GetRandomPercent > 30
                    Set RandomFactor To GetRandomPercent
                    If RandomFactor < 3
                        PlaySound AMBDLC04BoatArrivalBell
                    ElseIf RandomFactor < 6
                        PlaySound AMBDLC04PungaSprayRinging
                    ElseIf RandomFactor < 9
                        PlaySound AMBPittCrowdCheer01
                    ElseIf RandomFactor < 12
                        PlaySound DRSDeathclawCageClose
                    ElseIf RandomFactor < 15
                        PlaySound DRSDLC05HangarClose
                    ElseIf RandomFactor < 18
                        PlaySound DRSMetalHeavySingle01Close
                    ElseIf RandomFactor < 21
                        PlaySound FXExplosionDebrisMansion
                    ElseIf RandomFactor < 24
                        PlaySound NPCBrahminIdleGrazingLeft
                    ElseIf RandomFactor < 27
                        PlaySound NPCDeathClawCageExit
                    ElseIf RandomFactor < 30
                        PlaySound NPCDeathclawIdleClawScrape
                    ElseIf RandomFactor < 33
                        PlaySound NPCFeralGhoulRadiate
                    ElseIf RandomFactor < 36
                        PlaySound NPCFeralGhoulSeizureLong
                    ElseIf RandomFactor < 39
                        PlaySound NPCHillfolkJugLPM
                    ElseIf RandomFactor < 42
                        PlaySound NPCHumanSuicideGeneral
                    ElseIf RandomFactor < 45
                        PlaySound OBJDLC05ClawVoice01
                    ElseIf RandomFactor < 48
                        PlaySound OBJDLC05ClawVoice02
                    ElseIf RandomFactor < 51
                        PlaySound OBJDLC05ClawVoice03
                    ElseIf RandomFactor < 54
                        PlaySound OBJDLC05HealingArchHeal
                    ElseIf RandomFactor < 57
                        PlaySound OBJDLC05ProbeAlienA01
                    ElseIf RandomFactor < 60
                        PlaySound OBJDLC05ProbeAlienB02
                    ElseIf RandomFactor < 63
                        PlaySound QSTAlienRadio02
                    ElseIf RandomFactor < 66
                        PlaySound QSTBirthStart
                    ElseIf RandomFactor < 69
                        PlaySound QSTEnclaveTroopsMoving2D
                    ElseIf RandomFactor < 72
                        PlaySound QSTFadeToWhiteD
                    ElseIf RandomFactor < 75
                        PlaySound QSTInhibitorPulseDistant
                    ElseIf RandomFactor < 78
                        PlaySound QSTPartyClapping2D
                    ElseIf RandomFactor < 81
                        PlaySound QSTPartyNoiseMaker2D
                    ElseIf RandomFactor < 84
                        PlaySound QSTSiloLaunch
                    ElseIf RandomFactor < 87
                        PlaySound VOCBehemothSigh
                    ElseIf RandomFactor < 90
                        PlaySound VOCDLC04MaleChildGiggle
                    ElseIf RandomFactor < 93
                        PlaySound VOCDLC04MaleChildOooh
                    ElseIf RandomFactor < 96
                        PlaySound VOCDLC04MaleChildSnarl
                    ElseIf RandomFactor < 100
                        PlaySound VOCRobotLibertyPrimeCombat23
                    EndIf
                EndIf
            EndIf
            Set RadTimer To 0
        Else
            Set RadTimer To RadTimer + GetSecondsPassed
        EndIf
    EndIf
        
    ; Ghul-Effekte
    If RadState > 0 && IsGhoul > 0
        If IsGhoul == 1
            If GetRandomPercent < 30
                Set ApplyGhoulFx To 1
            EndIf
            If GetRandomPercent < 40
                Set ApplyGhoulSound To 1
            EndIf
            If RadMode == 3 && Player.GetAv RadiationRads < 601    
                Player.CastImmediateOnSelf wlwIngRadBomb
            EndIf
        ElseIf IsGhoul == 2 
            If Player.GetItemCount wlwWpnGhoulGrenade < 3
                Player.AddItem wlwWpnGhoulGrenade 3
            EndIf
            If GetRandomPercent < 50
                Set ApplyGhoulFx To 1
            EndIf
            If GetRandomPercent < 80
                Set ApplyGhoulSound To 1
            EndIf
            If DismissTimer > -1
                Set DismissTimer To DismissTimer - 1
            EndIf
            If Player.HasPerk wlwPerkGhoulFollower && RadMode == 3 && DismissTimer < 0
                Set CanRecruitGhoul To 1
            Else
                Set CanRecruitGhoul To 0
            EndIf
            If RadMode == 3 && Player.GetAv RadiationRads < 801
                Player.CastImmediateOnSelf wlwIngRadBomb
            EndIf
        EndIf
        If ApplyGhoulFx == 1
            ; In naechster Version weg
            RiMod wlwFXGhoulView1a
            RiMod wlwFXGhoulView1b
            RiMod wlwFXGhoulView2a
            RiMod wlwFXGhoulView2b
            Set RandomFactor To GetRandomPercent
            If RandomFactor > 75
                IMod wlwFxGhoulHalluzination1
            ElseIf RandomFactor > 50
                IMod wlwFxGhoulHalluzination2
            ElseIf RandomFactor > 25
                IMod wlwFxGhoulHalluzination3
            Else
                IMod wlwFxGhoulHalluzination4
            EndIf
            Set ApplyGhoulFx To 0
        EndIf
        If ApplyGhoulSound == 1
            Set RandomFactor To GetRandomPercent
            If RandomFactor > 75
                PlaySound wlwNPCFeralGhoulAlert
            ElseIf RandomFactor > 50
                PlaySound wlwNPCFeralGhoulAware
            ElseIf RandomFactor > 25
                PlaySound NPCFeralGhoulSeizureLong
            Else
                PlaySound NPCFeralGhoulSeizureShort
            EndIf
            Set ApplyGhoulSound To 0
        EndIf
    EndIf

End

[Boedel]

Mit massivem Munitionsverbrauch habe ich mich dann doch durch die Ameisenquest gekämpft

Finde es echt klasse wie viel Action du ins Ödland gepflanzt hast. An jeder Ecke patrouillieren irgendwelche Gruppen, denen man sich anschließen und mitkämpfen kann
Die eigentlichen Quests werden da glatt zur Nebensache...

[Boïndil]

Danke dir Wem der Trubel nicht gefällt, der kann übrigens gerne einzelne Spawn-Systeme im WLW-Menu deaktivieren, begrenzen oder die Spawn-Obergrenze runter stellen. Wenn alles aktiv ist, mag es manchem Spieler (oder seiner Hardware) doch zuviel sein.

Hier zwei neue Videos. Im einen zeige ich, wie es neu um Citadel aussieht. Es ging mir auf den Sack, wie langweilig das da ist und wie es die eine Hälfte der Bruderschaft nicht kratzt, was auf der anderen Seite passiert.
Es hat eigentlich damit angefangen, dass es seit langer Zeit in der Nähe des Haupttors einen Spawn von Raiderinnen durch WLW gibt und auf der anderen Seite einen Mehrspawn von Muties, die jeweils die Wachen aufgemischt haben. Also habe ich neue Gruppen eingebaut, die darauf reagieren, wer wo angreift und dann zur Verstärkung kommen.
Musste tatsächlich jeweils die Gesunhdeit der Raider und Mutanten runterschrauben, wenn sie da in die Nähe kommen, sonst würden die Kämpfe endlos dauern und die Bruderschaft könnte zu arg dezimiert werden. Man kann natürlich mithelfen, man kann aber auch einfach nur zuschauen. Ausserdem möchten die meisten sicher nicht jedes Mal wieder sich eine halbe Stunde lang durch knallharte Gegner wühlen müssen, um in die Citadel zu kommen.

Ohne Glitch kann es kein Fallout 3-Video sein, der f*** Sammler hat die Waffe falsch in der hand, was aber nicht meine Schuld ist.

Im anderen Video zeige ich kurz, was passiert, wenn man im Hardcore-Modus zum Plündernden Ghul wird, man muss also schon hartgesotten sein. Da zeigen sich auch die Grenzen dieser Spielweise. Wenn man etwa Tobar oder Catherine feindlich macht und sie töten würde, könnte man Quests gefährden. Deshalb habe ich die Essential gelassen, d.h. sie sind untötbar. Ich finde es durchaus reizvoll, mal als Ghul zu zocken, aber es eignet sich halt wirklich mehr zum End-Game von gelangweilten Bösewichten.
Klar sollten etwa die Beziehungen zur Bruderschaft trotz Verbrechen wird völlig normalisiert werden und man sollte mit den Quests anschliessend weiterfahren können, wenn man geheilt wird. Logisch ist das alles aber nicht mehr.
https://www.youtube.com/watch?v=e7Hj9sjq3Sk
Man sieht aber auch die neuen Effekte bei der Umwandlung, die man im jeden Modus hat, sieht immersiver aus.

[Boïndil]

So, und hier noch ein Video, wie ich den Tenpenny als Plündernder Ghul einnehme. Vorsicht, nix für schwache Nerven, das Video enthält Brutalität und Menschenfresserei
Würde ich allerdings nie tun, wenn es nicht zum Testen gewesen wäre. Als Ghul kriegt man ja dann automatisch den Kannnibalen-Perk.

Roy Phillips hat überhaupt keine Probleme damit, dass du Ghul geworden bist, ausserdem kann man da im Service-Zugang gleich noch drei Ghule als Begleiter rekrutieren, die ihn auch nicht angreifen.
Habe inzwischen noch weiter rumgeschraubt, z.B. lasse ich meine zusätzlich gespawnten Tenpenny-Bewohner(die man aussen im Video sieht) fliehen, sobald die Ghule los sind. Sonst würde Roy Philips denen endlos nachrennen.
Beim dritten Test-Durchgang bin ich dann noch voll in einen bekannten Bug gelaufen und zwar, dass das Spiel den Turm nicht als befreit erkennt und damit wird er auch nicht neu besiedelt. Ist halt schwache Programmierung, wie üblich. Das Spiel beendet zuerst die MS12-Quest und startet MS12fin(die Bezugsquest), die Funktionen dahinter warten aber dumm ab, bis 21 Tenpenny-Bewohner gestorben sind. Da steckt einer irgendwo fest, wird vergessen oder einer der Bewohner ist vorher gestorben oder wurde als Sklave nach Paradise Falls geschickt und schon gibts einen Plotstopper. Dass das Script hängt, wenn einer versklavt wurde, ist ein grober Bock, da muss man schon sehr kurzsichtig sein, um das zu vergessen. An dem Bug sitze ich gerade, kann man mit wenigen Zeilen fixen, allerdings nicht rückwirkend. Bei mir wirds allerdings dran liegen, dass irgendeiner ausser Sichtweite gekillt wurde und dass so der Zähler nicht erhöht wurde. Dass ist eine grössere Knacknuss, wie finde ich raus, was mit 21 Bewohnern los ist, ohne ein riesiges Script coden zu müssen.

Edit
Der Fehler liegt nicht an der Versklavung, eher daran, dass mal ein Bewohner gekillt wird, wenn sein Script nicht funktioniert. Das kann passieren, wenn sich der Spieler zwischen den Stockwerken bewegt, während gleichzeitig einer gekillt wird. Wahrscheinlich setzt dann das Script aus. Das kann man fixen.

Edit 2
Klappt jetzt einwandfrei, nach ein paar Tagen ist der Tenpenny wieder voll funkionsfähig mit eingezogenen Ghulen und zwei Händlern. Habe tatsächlich zwei NPCs übersehen, das war kein Bug.
Bin aber wieder gerade im Modding-Rausch, als ich merkte, dass das ja ein voll funktionsfähiges Spielerhaus mit Möglichkeiten zum Handeln für Plündernde Ghule ist. Muss dann mal abchecken, wie es mit Underworld ist, ob der Spieler da rein kann. Aber selbst wenn, die Route zum Tenpenny ist einfacher als durch die Stadt vor allem, wenn einem jeder hasst.

Also füge ich jetzt dem Spieler den Schlüssel zur Suite zu, wenn er mit Roy Philips nach dem Einzug spricht. Eigentlich hätte ich gute Lust, der Suite einen kaufbaren Ghul-Stil zu geben, mit ein wenig Gore, spezieller Atmosphäre und vielleicht einem Ghul-Butler. Okay, der Stil mag dann nicht jedem gefallen, aber sehen wir es mal so: nur mit WLW oder einem anderen Mod ist die Suite auf diese Weise noch freischaltbar.
Dann wäre noch je ein Bar-Personal und ein Doktor wünschenswert, diese werden nämlich nicht ersetzt, wie die anderen zwei Händler. Aussen hat es schon einen Spawn von Tenpenny-Ghulen, aber innen wären auch noch ein paar wünschenswert.

[Boïndil]

Bin immer noch dran, der Tenpenny funktioniert. Man kann oder sollte sich leider nicht zum Plündernden Ghul wandeln, bevor man die Schlüssel zum Generator-Raum hat, sonst kommt man nicht an die ran, sonst klappt aber alles hervorragend, man kriegt jetzt die Player-Suite des Tenpenny, wenn man nach der Quest mit Roy Philips redet. Bei Masters kann man dann regulär Themes kaufen.
Wenn man die WLW-Lighting aus dem WLW-Paket nutzt, kriegt man auch düsterere Beleuchtungsstile, wenn der Tenpenny von den Ghulen bezogen wurde. Die WLW-Lighting hat WLW nicht als Master, man hat aber trotzdem ein paar Zusatzfunktionen gegenüber der Standalone-Variante.
Wollte zuerst noch einen Stil Ghul kreieren, aber wer mal im GECK in die Player-Suite schauen möchte, sieht, was das für eine Gewaltsarbeit ist, ein weiteres Theme zu erstellen. Hatte sogar mal begonnen, in einem Duplikat der Suite ein wenig passende Deko und Beleuchtung einzubauen, aber damit ist die Arbeit nicht getan, ein voll funktionsfähiges Theme zu machen.
Denke, es ist wichtiger, nochmals über Land zu ziehen und verbleibende Quests zu erledigen. Damit kann ich am Besten das Balancing verbessern und noch Lücken schliessen und Bugs fixen, vielleicht auch einige Tweaks einbauen.
Zuerst muss ich mich aber noch von meiner Ghul-Form heilen, was man ja im Hardcore-Modus nur im Dunwich-Gebäude kann. Rein ist einfach, aber wenn man sich geheilt hat, sollte man die Beine unter die Arme nehmen. Werde nach dieser Erfahrung die Zeit noch ein wenig erhöhen, bis man zurück verwandelt wird, damit man einige Sekunden mehr hat, um zu fliehen. Sowas kann man nicht regulär ohne eine Begleiter-Armee überstehen, jeder Ghul darin kann dich alleine fertig machen. Aber okay, das Dunwich-Gebäude war schon in Vanilla Hardcore.
Nebenbei ist es sogar sinnvoll, gleich auch das Krivbeknih aus Point Lookout mitzunehmen, dann muss man nicht zwei Mal rein.

Und hier das Video. Man kann also schon jetzt relativ gefahrlos entkommen, wenn man sofort abhaut, wollte hier zeigen, was passiert, wenn man das nicht tut.

[Boedel]

Da hat man ja gar keine Chance lebend herauszukommen
Betrifft das nur die plündernde Ghulform, oder? Also die Änderungen im Tennpenny.

[Boïndil]

Man kann bereits jetzt entkommen, wenn man sofort losrennt. Gegenüber dem Video habe ich jetzt noch ein paar Sekunden hinzu gegeben, bevor die Wandlung nach dem Klick auf den Obelisk einsetzt. Ausserdem habe ich die Höhle da unten ein wenig besser beleuchtet, vor allem mit Höhlen-Pilzen, die einem die Richtung raus zeigen. Eine unbenutzte Ecke bei der Treppe habe ich noch ein wenig gruseliger mit Licht-Effekten gemacht.

Man kriegt den Schlüssel zur Suite neu auf jeden Fall, wenn man Roy Phlips hilft, egal wie man aussieht. Auch die Themes kann man bei Masters kaufen und die zusätzlichen Bartender und die Tenpenny-Bewohner kriegt man ebenfalls.

Vorher kriegte man ja nur Zugang zur Suite, wenn man Megaton hochgehen liess, während Roy Philips einem nur ein paar Korken gab. Wobei man auch sagen muss, dass die Suite so ungefähr das schlechteste Spielerhaus ist, das man kriegen kann, ein weiterer Grund, wieso ich nicht noch mehr Zeit da versenkt habe.

Wie gesagt, kann man relativ einfach aus dem Gebäude rennen, aber aussen kann einem auch mal ein Behemoth erwarten. Musste bis Rockopolis rennen, bis ich mal nicht von irgendwas beschossen wurde.



Edit
Beim Modding führt eines zum anderen. Kam zufällig im Sniper-Haus in der Nähe von Alexandria Arms durch, das kann man als zusätzliches Spielerhaus nutzen, wenn man damit leben kann, dass ab und zu ein paar Typen respawnen. Lagern geht auf jedem Fall in jedem Behälter des Hauses, alle respawnen nicht. Ausserdem habe ich sie jetzt alle dem Spieler zugewiesen, damit sich keiner daran vergreift. Werkbank und Labor habe ich da ja schon vor langer Zeit hinzugefügt.

Dann ist mir noch bei einem letzten Test aufgefallen, dass Begleiter nicht feindlich werden, wenn man sich im Hardcore-Modus verwandelt, daran sitze ich gerade. Da ich sowieso dabei bin, habe ich vor, bei den Belgeitern nochmals ein wenig Performance rauszuholen. Ich meine, die von Bethesda hatten z.B. eine Abfrage auf Jericho drauf, die alle 0.0015 Sekunden abfragt, ob sich der Spieler in einer gewissen Distanz zu Jenny Stahl befindet. Solche Distanzmessungen sind ein grober Performance-Fresser, deshalb setzte ich die normalerweise hinter einen nützlichen Intervall, z.B. nur alle 20 Sekunden. Das habe ich bereits auf Jericho entfernt, da das sowieso eine sinnlose Funktion ist. Vielleicht lässt sich da noch mehr rausholen.

Edit 2
Falls sich mal einer das hübsche Script von Starpaladin Cross ansehen möchte:

scn StarPaladinCrossSCRIPT

Spoiler:

; Fallout Variablen
short HasBeenHired
short WeaponOut
short CombatStyleRanged
short CombatStyleMelee
short IsFollowingDefault
short IsFollowingShort
short IsFollowingLong
short Waiting
; WLW Variablen
short ButtonPressed
short CurrentTask
short RessurectMessage
short RemainingTime
short StatModifier
short UncrippleRate
short HealRate
float DeadTimer
float HealTimer
float HealLimit
float HealthPerc
short SandboxTimer 

Begin OnLoad
    If GetDead == 0
        Set CurrentTask To 5
    EndIf
End

Begin OnCombatEnd
    ; Vanilla-Auto-Heilung
    If wlwQuest.TeamHealMode == 0 && CurrentTask == 0 && GetPlayerTeammate == 1
        Set CurrentTask To 5
    EndIf
End

Begin OnStartCombat Player
    If GetPlayerTeammate == 1
        Set CurrentTask To 7
    EndIf
End

Begin GameMode


    If CurrentTask == 0 ; Begleiter-Funktionen
        If HealTimer > wlwFollowersHealInterval
            If GetPlayerTeamMate
                ; Begleiter entlassen im Ghul-Hardcore-Modus
                If Player.HasPerk wlwPerkGhoulHardCoreMode
                    Set CurrentTask To 7
                EndIf
                ; Sandbox
                If wlwQuestGame.SandboxAllowed == 1 
                    If Waiting == 0 && GetInFaction wlwTypeFollowerFaction && wlwQuestGame.SandboxType != GetAv Variable07
                        SetAv Variable07 wlwQuestGame.SandboxType
                        Evp
                    EndIf
                Else
                    SetAv Variable07 0
                EndIf            
                ; Heilen, wenn notwendig
                If wlwQuest.TeamHealMode == 1 
                    Set HealLimit To (10 + Player.GetPermAV Medicine) / 100
                    If HealLimit > 0.85
                        Set HealLimit To 0.85
                    EndIf
                    If GetHealthPercentage < HealLimit        
                        Set CurrentTask To 4        
                    EndIf
                EndIf
            EndIf
            Set HealTimer To 0
        Else
            Set HealTimer To HealTimer + GetSecondsPassed
        EndIf
    

    ElseIf CurrentTask == 1 ; DeadTime
        If DeadTimer > wlwFollowersKnockedOutTime
            Set CurrentTask To 3
        Else
            If DeadTimer == 0
                wlwFollowerCrossMapMarker.enable
                wlwFollowerCrossMapMarker.MoveTo StarPaladinCrossREF
                wlwFollowerCrossSignRef.Enable
                wlwFollowerCrossSignRef.MoveTo StarPaladinCrossREF
                ShowMessage wlwFollowerKnockedOutMsg
            EndIf
            Set DeadTimer To DeadTimer + GetSecondsPassed        
        EndIf
    ElseIf CurrentTask == 2 ; Wiederbeleben
        Set Followers.TaskType To 1
        Set Followers.TaskRef To 5
        Set CurrentTask To 0
    ElseIf CurrentTask == 3 ; Endgueltig killen
        ShowMessage FollowerMessageDeadStarPaladinCross
        Set CurrentTask To 7
    ElseIf CurrentTask == 4  ; Partielles Regenerieren mit Stimpaks
        If GetItemCount Stimpak > 0
            PlayIdle 3rdPSpecialIdleStimpak
            PlaySound NPCHumanUsingStimpak
            RemoveItem Stimpak 1 1
            CastImmediateOnSelf wlwFollowerStimpak
        ElseIf Player.GetItemCount Stimpak > 0
            PlayIdle 3rdPSpecialIdleStimpak
            PlaySound NPCHumanUsingStimpak
            Player.RemoveItem Stimpak 1 1
            CastImmediateOnSelf wlwFollowerStimpak
        EndIf
        Set CurrentTask To 0
    ElseIf CurrentTask == 5 ; Weitgehendes Regenerieren ohne Stimpaks
        CastImmediateOnSelf wlwMediPak
        Set CurrentTask To 0
    ElseIf CurrentTask == 6 ; Stats reseten
        Set StatModifier To (Player.GetPermAV Agility + 2)
        ForceAv Agility StatModifier
        Set StatModifier To (Player.GetPermAV Strength + 2)
        ForceAv Strength StatModifier
        Set StatModifier To (Player.GetPermAV Endurance + 2)
        ForceAv Endurance StatModifier
        Set StatModifier To (GetAv Endurance * 40) + (Player.GetLevel * 20)
        ForceAv Health StatModifier
        Set CurrentTask To 0
    ElseIf CurrentTask == 7 ; Aus Team entlassen
        Set Followers.FollowerCount To Followers.FollowerCount - 1
        If Followers.FollowerCount <= 0
            Set Followers.PlayerHasFollower To 0
        EndIf
        Set Waiting To 0
        Set Followers.StarPaladinCrossHired To 0
        Set Followers.StarPaladinCrossFired To 1
        SetPlayerTeamMate 0
        RemoveFromFaction FollowerFaction
        wlwFollowerCrossMapMarker.Disable
        wlwFollowerCrossSignRef.Disable
        Set CurrentTask To 0
    EndIf    
End

Begin OnActivate
    If IsActionRef Player == 1 
        If CurrentTask == 1 && Followers.TaskType == 0
            Set RessurectMessage To 1
            ShowMessage wlwFollowerRessurectMenuMsg
        ElseIf CurrentTask == 1 && Followers.TaskType > 0
            Set RessurectMessage To 0
            ShowMessage wlwFollowerRessurectWaitMsg
        Else
            Set RessurectMessage To 0
            Activate
        EndIf
    EndIf
End

Begin MenuMode
    ; Menu Wiederbelebung
    If RessurectMessage == 1
        Set ButtonPressed To GetButtonPressed
        If ButtonPressed == -1 ; Void
            Return
        ElseIf ButtonPressed == 0 ; Abbrechen oder andere Buttons nicht vorhanden
            Set RemainingTime To wlwFollowersKnockedOutTime / 60
            If RemainingTime < 1
                Set RemainingTime To 1
            EndIf
            ShowMessage wlwFollowerRessurectImpossibleMsg RemainingTime
        ElseIf ButtonPressed == 1 ; Wiederbeleben 1 MediPak
            If Player.GetItemCount wlwMediPak > 0
                Player.RemoveItem wlwMediPak 1 0
                Set CurrentTask To 2
            EndIf
        ElseIf ButtonPressed == 2 ; Wiederbeleben 2 MediPak
            If Player.GetItemCount wlwMediPak > 1
                Player.RemoveItem wlwMediPak 2 0
                Set CurrentTask To 2
            EndIf
        ElseIf ButtonPressed == 3 ; Wiederbeleben 1 Stimpak
            If Player.GetItemCount Stimpak > 0
                Player.RemoveItem Stimpak 1 0
                Set CurrentTask To 2
            EndIf
        ElseIf ButtonPressed == 4 ; Wiederbeleben 3 Stimpaks
            If Player.GetItemCount Stimpak > 2
                Player.RemoveItem Stimpak 3 0
                Set CurrentTask To 2
            EndIf
        ElseIf ButtonPressed == 5 ; Wiederbeleben 6 Stimpaks
            If Player.GetItemCount Stimpak > 5
                Player.RemoveItem Stimpak 6 0
                Set CurrentTask To 2
            EndIf
        EndIf
        If ButtonPressed >= 0
            Set DeadTimer To 0
            Set RessurectMessage To 0
        EndIf
    EndIf
End

Begin OnDeath
    ; Auf Tod reagieren: sofortiger oder aufgeschobener Tod
    If Followers.StarPaladinCrossHired == 1
        SetPlayerTeamMate 0
        If wlwQuest.TeamDeathMode == 1
            Set CurrentTask To 1
        ElseIf wlwQuest.TeamDeathMode == 0
            Set CurrentTask To 3
        EndIf
    EndIf
    If IsKiller Player == 1
        RewardKarma -100
    EndIf
End

[Boïndil]

Weil es so schön war, noch ein abschliessendes Test-Video zu den Reaktionen der Begleiter, wenn man sich im Hardcore-Modus verwandelt. Es ist nur 27 Sekunden lang



Gibt ja mnachmal schon Arbeit, alles auszutesten. Z.B. sich zum Ghul wandeln, vor den Begleitern abhauen, sich zurück wandeln, Begleiter wieder rekrutieren, dabei abchecken, ob alle anderen Gruppen auch wieder friedlich sind, ...
Sieht zwar im Moment gut aus, es waren auch alle Begleiter wieder wie zu Erwarten auffind- und rekrutierbar.

Dabei checke ich gerade die Schlacht vor dem Kapitol ab, es ist richtig episch. Aber nicht unbedingt genug und es ist zu einfach, weil es zuviele BoS im Vergleich zu den Mutanten hat. Das kann schwanken, da die Vanilla-Spawns auf dem Platz nicht immer ausgelöst werden. Da findet man teilweise leere Schützengräben, während man hinten eine Armee BoS zur Verstärkung hat. Muss das noch genauer balancieren.

[Boïndil]

So, die Schlacht ums Kapitol in noch epischer

Das reagiert auf die Einstellungen zur Spawn-Begrenzung im WLW-Menu. Wenn man das runterstellt kriegt man Gruppen weniger. Den Schwierigkeitsgrad kann man steuern, indem man selbst vorprescht oder sich zurück hält.
Bin noch am Feinschliff vor dem Kapitol selbst, da passt es mir noch nicht so. Während man jetzt länger für den Weg dahin hat, geht die Schlacht vorne schon los und Talon und Enklave machen sich zum Teil gegenseitig fertig, ohne dass man was davon hat. Ich selbst reagiere mit meinen Spawns auf den Weg des Spielers, während in Vanilla alles dumm sofort startet und dabei auch Performance verschwendet. Mal sehen, ob ich das noch verzögern kann, bis der Spieler näher ist. Schraube ausserdem noch am Todeskrallen-Käig rum, damit der nicht ausser Sichtweite des Spielers geöffnet werden kann, was viel zu oft passiert.

[Boedel]

Gehört Bittercup bei WLW standardmäßig zu den Begleitern?
Bin gerade im Tenpenny Tower und wollte die Ghule freilassen. Da ich mit der aktuellen 2.74 spiele, weiß ich jetzt nicht ob mir da was durch die Lappen geht da du dort ja einiges noch geändert hast?

Ich könnte auch erstmal auf Bobblehead-Jagd gehen

edit: So ein Dialog ist doch was feines