Eure Modding-Pläne für Fallout 4

[Boïndil]

Habe vorhin noch das Menu für das Dialog-Licht und die Auto-Ego-Ansicht, wenn man in der Third zoomt, eingebaut.
Man kann jetzt aus sieben verschiedenen Lichtquellen wählen, zwei Grün-Töne, zwei Gold-Töne, zwei Blau-Töne, ein neutrales Licht.

Hier mal der Stand meines Controller-Scripts mit den Menus, sind fast fünfhundert Zeilen, wobei die grossen Funktionen in den anderen Scripten sind, etwa Gore(288 Zeilen) oder Effects(689 Zeilen).

Scriptname THEW:THEWController_V_01_00 extends ObjectReference

Spoiler:

Group Common
    Quest Property THEWQuestUpdate Auto Const Mandatory
    Quest Property THEWQuest_V_01_00 Auto Const Mandatory
    THEW:THEWQuest_Gore_V_01_00 Property GoreQuest Auto Const Mandatory
    THEW:THEWQuest_Effects_V_01_00 Property EffectQuest Auto Const Mandatory
    THEW:THEWQuest_Misc_V_01_00 Property MiscQuest Auto Const Mandatory
    GlobalVariable Property GameHour Auto Const Mandatory
    GlobalVariable Property THEWVersion Auto Const Mandatory
    Sound Property EffectSoundUIStart Auto Const Mandatory
    Actor Property Player Auto Const Mandatory
    bool Property IsUninstalled Auto
EndGroup

Group Misc
    Spell Property THEWPerspectiveManagerSpell Auto Const Mandatory
EndGroup

Group Messages
    Message Property THEWMenu0Main Auto Const Mandatory
    Message Property THEWMenu1Gore Auto Const Mandatory
    Message Property THEWMenu1Presets Auto Const Mandatory
    Message Property THEWMenu1Settings Auto Const Mandatory
    Message Property THEWMenu1MiscEffects Auto Const Mandatory
    Message Property THEWMenu2EffectsAutoEgo Auto Const Mandatory
    Message Property THEWMenu2EffectsDialogLight Auto Const Mandatory
    Message Property THEWMenu2PresetBase Auto Const Mandatory
    Message Property THEWMenu2PresetInterior Auto Const Mandatory
    Message Property THEWMenu2PresetDay  Auto Const Mandatory
    Message Property THEWMenu2PresetNight Auto Const Mandatory
    Message Property THEWMenu2PresetDawn Auto Const Mandatory
    Message Property THEWMenu2PresetDusk Auto Const Mandatory
    Message Property THEWMenu2PresetGeneric1 Auto Const Mandatory
    Message Property THEWMenu2PresetGeneric2 Auto Const Mandatory
    Message Property THEWMenu2PresetGeneric3 Auto Const Mandatory
    Message Property THEWMenu2Info Auto Const Mandatory
    Message Property THEWMenu2UninstallConfirm Auto Const Mandatory
    Message Property THEWMenu3Filter Auto Const Mandatory
    Message Property THEWMenu3CopyFrom Auto Const Mandatory
    Message Property THEWMenu3CopyTo Auto Const Mandatory
    Message Property THEWMenu4FilterSaturation Auto Const Mandatory
    Message Property THEWMenu4FilterBrightness Auto Const Mandatory
    Message Property THEWMenu4FilterContrast Auto Const Mandatory
    Message Property THEWMenu4FilterColorShift Auto Const Mandatory
    Message Property THEWMenu4FilterColorStyle Auto Const Mandatory
    Message Property THEWMenu4FilterDofNear Auto Const Mandatory
    Message Property THEWMenu4FilterDofFar Auto Const Mandatory
    Message Property THEWMenu4FilterBloom Auto Const Mandatory
    Message Property THEWMenu4FilterEffects Auto Const Mandatory
    Message Property THEWMenuInfoOpen Auto Const Mandatory
    Message Property THEWMenuInfoFirstStart Auto Const Mandatory
    Message Property THEWMenuUninstallConfirmed Auto Const Mandatory
EndGroup
; Preset-ID
; -1 Default
; 0 Interior
; 1 Day
; 2 Night
; 3 Dawn
; 4 Dusk
; 5 Preset 1
; 6 Preset 2
; 7 Preset 3
int ActivePreset = -1
; Applied preset
int ForcedPreset = 0
; Zweimaliges Wirken verhindern
bool MenuOpen = false
bool StartOnce

; - Menus Level 0 --------------------------------------------------------
; Haupt-Menu
bool MenuMainInit
Function MenuMain()
    If MenuMainInit == false
        MenuMainInit = true
        EffectQuest.LockUpdate()
        GoreQuest.LockUpdate()
        MiscQuest.LockUpdate()
        ActivePreset = EffectQuest.CurrentPreset ; Last active preset
    EndIf
    int selected = THEWMenu0Main.Show()
    If (selected == 0)                ; Back
        MenuOpen = false
        MenuMainInit = false
        If EffectQuest.ForcedPreset > 0
            EffectQuest.ApplyPreset(ForcedPreset, true)
        Else
            EffectQuest.ResetAmbient()
        EndIf
        EffectQuest.UpdateEffects()
        GoreQuest.UpdateGore()
        MiscQuest.UpdateDialogLight()
    ElseIf (selected == 1)            ; Presets
        MenuPresets()
    ElseIf (selected == 2)            ; Gore
        GoreQuest.Preview()
        MenuGore()                    
    ElseIf (selected == 3)            ; Placeholder

    ElseIf (selected == 4)            ; Placeholder

    ElseIf (selected == 5)            ; Placeholder

    ElseIf (selected == 6)            ; Placeholder

    ElseIf (selected == 7)            ; Placeholder

    ElseIf (selected == 8)            ; Settings
        MenuSettings()
    ElseIf (selected == 9)            ; Info
        MenuInfo()
    EndIf
EndFunction

; - Menus Level 1 --------------------------------------------------------
Function MenuPresets()
    int active = ActivePreset + 1
    float currenthour = GameHour.GetValue()
    float hour = Math.Floor(currenthour) as float
    float minutes = (0.6 * (currenthour - hour)) * 100
    int selected = THEWMenu1Presets.Show(hour, minutes, active as float, EffectQuest.InteriorEnabled as float, EffectQuest.DayEnabled as float, EffectQuest.NightEnabled as float, EffectQuest.DawnEnabled as float, EffectQuest.DuskEnabled as float)
    If (selected == 0) ; Back
        MenuMain()
    ElseIf (selected > 0) ; Preset selection
        MenuPresetSettings(selected - 2) ; Consistent index, see THEWQuest_Effects: -1: Default, 0 Interior, ...
    EndIf
EndFunction

Function MenuGore()
    float treshold = GoreQuest.GoreTreshold * 100
    float goretype = (GoreQuest.GoreType + 1) as float
    int selected = THEWMenu1Gore.Show(GoreQuest.GoreEnabled as float, goretype, treshold, GoreQuest.GoreEffects as float)
    If (selected == 0)                ; Back
        GoreQuest.PreviewEnd()
        MenuMain()
    ElseIf (selected == 1)            ; Disable Gore
        GoreQuest.DisableGore()
        MenuGore()
    ElseIf (selected == 2)            ; Enable Gore
        GoreQuest.EnableGore()    
        GoreQuest.Preview()
        MenuGore()        
    ElseIf (selected == 3)            ; Gore Type Minus
        GoreQuest.ChangeGoreType(-1, true)
        MenuGore()
    ElseIf (selected == 4)            ; Gore Type Plus
        GoreQuest.ChangeGoreType(1, true)
        MenuGore()
    ElseIf (selected == 5)            ; Treshold Minus
        GoreQuest.SetGoreTreshold(GoreQuest.GetGoreTreshold() - 0.05)
        MenuGore()
    ElseIf (selected == 6)            ; Treshold Plus
        GoreQuest.SetGoreTreshold(GoreQuest.GetGoreTreshold() + 0.05)
        MenuGore()
    ElseIf (selected == 7)            ; Additional effects off
        GoreQuest.EnableAdditionalEffects(false)
        MenuGore()
    ElseIf (selected == 8)            ; Additional effects on
        GoreQuest.EnableAdditionalEffects()
        MenuGore()
    EndIf
EndFunction

Function MenuEffectsMisc()
    int selected = THEWMenu1MiscEffects.Show()
    If (selected == 0)                ; Back
        MenuMain()
    ElseIf (selected == 1)            ; Dialog Light
        MenuEffectsMiscDialogLight()
    ElseIf (selected == 2)            ; Auto Ego
        MenuEffectsMiscAutoEgo()
    EndIf
EndFunction

Function MenuSettings()
    int selected = THEWMenu1Settings.Show(EffectQuest.TimerInterval, GoreQuest.GoreInterval)
    If (selected == 0)                ; Back
        MenuMain()                
    ElseIf (selected == 1)            ; Effects Interval -
        If EffectQuest.TimerInterval > 1
            EffectQuest.TimerInterval = EffectQuest.TimerInterval - 0.05
        EndIf
        MenuSettings()
    ElseIf (selected == 2)            ; Effects Interval +
        If EffectQuest.TimerInterval < 5
            EffectQuest.TimerInterval = EffectQuest.TimerInterval + 0.05
        EndIf
        MenuSettings()
    ElseIf (selected == 3)            ; Gore Interval -
        If GoreQuest.GoreInterval > 0.05
            GoreQuest.GoreInterval = GoreQuest.GoreInterval - 0.05
        EndIf
        MenuSettings()
    ElseIf (selected == 4)            ; Gore Interval +
        If GoreQuest.GoreInterval < 3
            GoreQuest.GoreInterval = GoreQuest.GoreInterval + 0.05
        EndIf
        MenuSettings()
    ElseIf (selected == 5)            ; Show Infos Off
        EffectQuest.DebugOn = false
        MenuSettings()
    ElseIf (selected == 6)            ; Show Infos On
        EffectQuest.DebugOn = true
        MenuSettings()
    ElseIf (selected == 7)            ; Placeholder
        MenuSettings()
    ElseIf (selected == 8)            ; Info
        MenuInfo()
    ElseIf (selected == 9)            ; Uninstall
        MenuUninstall()
    EndIf
EndFunction

; - Menus Level 2 --------------------------------------------------------
Function MenuPresetSettings(int presetType)
    If EffectQuest.ControllerActivePreset != presetType
        EffectQuest.ControllerActivePreset = presetType ; For messagebox condition in menus CopyFrom, CopyTo
        EffectQuest.ApplyPreset(presetType, true)
    EndIf
    int selected = -1
    float isApplied
    If presetType == -1
        selected = THEWMenu2PresetBase.Show()
    ElseIf presetType == 0
        selected = THEWMenu2PresetInterior.Show(EffectQuest.InteriorEnabled as float)
    ElseIf presetType == 1
        selected = THEWMenu2PresetDay.Show(EffectQuest.DayEnabled as float)
    ElseIf presetType == 2
        selected = THEWMenu2PresetNight.Show(EffectQuest.NightEnabled as float)
    ElseIf presetType == 3
        selected = THEWMenu2PresetDawn.Show(EffectQuest.DawnEnabled as float)
    ElseIf presetType == 4
        selected = THEWMenu2PresetDusk.Show(EffectQuest.DuskEnabled as float)
    ElseIf presetType == 5
        If presetType == EffectQuest.ForcedPreset
            isApplied = 1.0
        EndIf
        selected = THEWMenu2PresetGeneric1.Show(isApplied)
    ElseIf presetType == 6
        If presetType == EffectQuest.ForcedPreset
            isApplied = 1.0
        EndIf
        selected = THEWMenu2PresetGeneric2.Show(isApplied)
    ElseIf presetType == 7
        If presetType == EffectQuest.ForcedPreset
            isApplied = 1.0
        EndIf
        selected = THEWMenu2PresetGeneric3.Show(isApplied)
    EndIf
    If selected == 0 ; Back to preset type, revert to the currently active preset, save current settings
        EffectQuest.ControllerActivePreset = -666
        EffectQuest.SaveToPreset(presetType)
        If EffectQuest.ForcedPreset > 0
            EffectQuest.ApplyPreset(ForcedPreset, true)
        Else
            EffectQuest.ApplyPreset(ActivePreset, true)
        EndIf
        MenuPresets()
    ElseIf selected == 1 ; Disable preset, only ambient presets can be enabled/disabled,  messagebox condition
        EffectQuest.EnablePreset(presetType, false) 
        MenuPresetSettings(presetType)
    ElseIf selected == 2 ; Enable, only ambient presets can be enabled/disabled,  messagebox condition
        EffectQuest.EnablePreset(presetType)
        MenuPresetSettings(presetType)
    ElseIf selected == 3 ; UnAapply preset, only generic presets 1-3 can be applied/unapplied,  messagebox condition
        EffectQuest.ForcedPreset = 0
        MenuPresetSettings(presetType)
    ElseIf selected == 4 ; Apply preset, only generic presets 1-3 can be applied/unapplied,  messagebox condition
        EffectQuest.ForcedPreset = presetType
        MenuPresetSettings(presetType)
    ElseIf selected == 5 ; Edit filters
        MenuPresetEditEffects(presetType)
    ElseIf selected == 6 ; Copy from other preset
        MenuCopyFrom(presetType)
    ElseIf selected == 7 ; Copy to other preset
        MenuCopyTo(presetType)
    EndIf
EndFunction

Function MenuEffectsMiscDialogLight()
    int selected = THEWMenu1Settings.Show(MiscQuest.DialogLightEnabled  as float, (MiscQuest.DialogLightType + 1) as float)
    If (selected == 0)                ; Back
        MiscQuest.ClearDialogLights()
        MenuEffectsMisc()                
    ElseIf (selected == 1)            ; Disable
        MiscQuest.DisableDialogLight()
        MenuEffectsMiscDialogLight()
    ElseIf (selected == 2)            ; Enable
        MiscQuest.EnableDialogLight()
        MenuEffectsMiscDialogLight()
    ElseIf (selected == 3)            ; Type -
        MiscQuest.ChangeDialogLightType(-1)
        MenuEffectsMiscDialogLight()
    ElseIf (selected == 4)            ; EType +
        MiscQuest.ChangeDialogLightType(1)
        MenuEffectsMiscDialogLight()
    EndIf
EndFunction

Function MenuEffectsMiscAutoEgo()
    float hasEgoSpell = Player.HasSpell(THEWPerspectiveManagerSpell) as float
    int selected = THEWMenu2EffectsAutoEgo.Show(hasEgoSpell)
    If (selected == 0)                ; Back
        MenuEffectsMisc()
    ElseIf (selected == 1)            ; Disable
        Player.RemoveSpell(THEWPerspectiveManagerSpell)
        MenuEffectsMisc()
    ElseIf (selected == 2)            ; Enable
        Player.AddSpell(THEWPerspectiveManagerSpell)
        MenuEffectsMisc()
    EndIf
EndFunction

; Mod Info
Function MenuInfo()
    int selected = THEWMenu2Info.Show(THEWVersion.GetValue())
    If (selected == 0)                ; Back
        MenuMain()
    EndIf
EndFunction

; Uninstallation
Function MenuUninstall()
    int selected = THEWMenu2UninstallConfirm.Show()
    If (selected == 0)                ; Back
        MenuSettings()
    ElseIf (selected == 1)            ; Uninstall
        IsUninstalled = true
        THEWQuestUpdate.Stop()
        THEWQuest_V_01_00.Stop()
        THEWMenuUninstallConfirmed.Show()
    EndIf
EndFunction

; - Menus Level 3 --------------------------------------------------------
; Menu filter selection
Function MenuPresetEditEffects(int presetType)
    int selected = THEWMenu3Filter.Show(EffectQuest.GetPresetValue(-2, 0), EffectQuest.GetPresetValue(-2, 1), EffectQuest.GetPresetValue(-2, 2), EffectQuest.GetPresetValue(-2, 3), EffectQuest.GetPresetValue(-2, 4), EffectQuest.GetPresetValue(-2, 5), EffectQuest.GetPresetValue(-2, 6), EffectQuest.GetPresetValue(-2, 8))
    If (selected == 0)
        MenuPresetSettings(presetType)
    ElseIf (selected > 0)
        MenuPresetEditEffect(presetType, selected - 1)
    EndIf
EndFunction

; Menu Copy from...
; Copies values of another preset to the active values
Function MenuCopyFrom(int presetType)
    int selected = THEWMenu3CopyFrom.Show()
    If (selected == 0)    ; Back
        MenuPresetSettings(presetType)
    ElseIf (selected > 0) ; 
        EffectQuest.ApplyPreset(selected - 2, true) ; Consistent index, see THEWQuest_Effects: -1: Default, 0 Interior, ...
        MenuPresetSettings(presetType)
    EndIf
EndFunction

; Menu Copy to...
; Copies active values to another preset
Function MenuCopyTo(int presetType)
    int selected = THEWMenu3CopyTo.Show()
    If (selected == 0)    ; Back
        MenuPresetSettings(presetType)
    ElseIf (selected > 0)
        EffectQuest.SaveToPreset(selected - 2) ; Consistent index, see THEWQuest_Effects: -1: Default, 0 Interior, ...
        MenuCopyTo(presetType)
    EndIf
EndFunction

; - Menus Level 3 --------------------------------------------------------
; Menu Filter
; For message boxes
; - use the right type(%.0f for types, %.0f for strength values)
Function MenuPresetEditEffect(int presetType, int effectId)
    int selected = -1
    float modifierMin
    float modifierMax
    float effectValue = EffectQuest.GetPresetValue(-2, effectId)
    If effectId == 0
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterSaturation.Show(effectValue)
    ElseIf effectId == 1
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterBrightness.Show(effectValue)
    ElseIf effectId == 2
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterContrast.Show(effectValue)
    ElseIf effectId == 3
        modifierMin = 1.0
        modifierMax = 3.0
        selected = THEWMenu4FilterColorShift.Show(effectValue)
    ElseIf effectId == 4
        modifierMin = 1.0
        modifierMax = 3.0
        selected = THEWMenu4FilterColorStyle.Show(effectValue)
    ElseIf effectId == 5
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterDofFar.Show(effectValue)
    ElseIf effectId == 6
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterDofNear.Show(effectValue)
    ElseIf effectId == 7
        modifierMin = 0.05
        modifierMax = 0.1
        selected = THEWMenu4FilterBloom.Show(effectValue)
    ElseIf effectId == 8
        modifierMin = 1.0
        modifierMax = 3.0
        selected = THEWMenu4FilterEffects.Show(effectValue)
    EndIf
    If selected == 0
        MenuPresetEditEffects(presetType)
    ElseIf selected == 1; Decrease effects ++
        EffectQuest.ApplyEffect(effectId, effectValue - modifierMax)
        MenuPresetEditEffect(presetType, effectId)
    ElseIf selected == 2; Decrease effects +
        EffectQuest.ApplyEffect(effectId, effectValue - modifierMin)
        MenuPresetEditEffect(presetType, effectId)
    ElseIf selected == 3; Disable effect
        EffectQuest.ApplyEffect(effectId, 0)
        MenuPresetEditEffect(presetType, effectId)
    ElseIf selected == 4; ; Increase effects -
        EffectQuest.ApplyEffect(effectId, effectValue + modifierMin)
        MenuPresetEditEffect(presetType, effectId)
    ElseIf selected == 5; ; Increase effects --
        EffectQuest.ApplyEffect(effectId, effectValue + modifierMax)
        MenuPresetEditEffect(presetType, effectId)
    EndIf
EndFunction

; - Events --------------------------------------------------------------------------
; Player activates controller in the inventory
; To Do: controller as weapon or armor?
Event OnEquipped(Actor reader)
    If (reader != Game.GetPlayer() || IsUninstalled)
        return
    EndIf
    ; To Do Auto Exit out of PipBoy
    If StartOnce == false
        StartOnce = true
        THEWMenuInfoFirstStart.Show()
    EndIf
    EffectSoundUIStart.Play(Player)
    Utility.WaitMenuMode(2.0)
    If MenuOpen == false
        MenuOpen = true
        MenuMain()
    Else
        THEWMenuInfoOpen.Show()
    EndIf
EndEvent
; Player activates controller outside inventory
; To Do: controller as weapon or armor?
Event OnActivate(ObjectReference reader)
    If (reader != Game.GetPlayer() || IsActivationBlocked() || IsUninstalled)
        return
    EndIf
    ; To Do Auto Exit out of PipBoy
    Utility.WaitMenuMode(1.0)
    If MenuOpen == false
        MenuOpen = true
        MenuMain()
    Else
        THEWMenuInfoOpen.Show()
    EndIf
EndEvent

[Auslieferator]

Du bist ja schon so ungeduldig wie ein Konsolero

...

EY! Obacht!

Is doch kein Wunder, das ich (wir) vor Ungeduld platzen könnten, oder?

(Gefühlte) Jahrhunderte lang auf Schmankerl warten, die für die PCler selbstverständlich geworden sind?

Ach du 9e....

[RazorX]

Du scheinst immr ein wenig an meinem Urteilsvermögen zu zweifeln, gehst aber immer von deinem High-Level-Spiel mit einer Begleiter-Armee und einer Backpack-Sammlung aus, dazu nicht mal im Überlebensmodus

...klar, ich stelle mit Stufe 102 jetzt mein Spiel auf Survival, wo ist denn da der Sinn? Oder ich starte neu, ohne die Story abzuschließen...und sehe alle Szenen immer wieder, bis es mich langweilt. Ich bezweifle mal stark, das der Survival-Modus schwerer ist, als mein Skyrim...vielleicht nerviger, aber nicht schwerer. Den Modus hätte es gleich geben sollen, bevor man zig Siedlungen aufbaut... Ob ich noch mal neu mit Survival starte weiss ich nicht, neue DLCs rücken ja schon wieder an.

Gibts eigentlich überhaupt was, das in diesem Creation Kit richtig funktioniert? Suchte nach Idle-Animationen für den Spieler, eine Sache, die man seit Fallout 3 am besten im Idle-Fenster eines Packages betrachtet.

...musste man dafür nicht die Archive komplett entpacken, vor allem, wenn man eigene Archive/eigene Dateinen/Replacer nutzte? Hab das noch nicht getestet, könnte da aber mal nachfragen.
Gibt auch Idle-Anis auf Nexus...könntest ja mal ansehen/testen...

Pack Brahmin gibts schon eine Weile. Kuck mal hier. Der Autor weist allerdings drauf hin, dass es mit dem aktuellen Patch (1.5) noch ungetestet ist. Ich kann leider auch nichts dazu sagen, da ich sie selbst nicht nutze. Bin nur drauf aufmerksam geworden, weil ich eine andere Mod des gleichen Erstellers nutze.

...danke, schau ich mir mal an. Muss natürlich mit EFF kompatibel sein und sollte keine eigenen Scripte fürs Management mitbringen.

[Boïndil]

Nerviger ist genau der Punkt. Die Schwierigkeit lässt sich aber kaum vergleichen. Ein Teil des Balancings hast du selbst im Griff und Strassenköter springen auf Level 20 immer noch glatt mit einem One-Hit-Kill durch mich durch, ein Schuss aus einem Gutsy killt mich ebenfalls.

Nein, man muss die Archive nicht entpacken, ging damals schon in Fallout 3 ohne. Die Preview-Fenster sind einfach grob fehlerhaft.
Man musss Dateien nur entpacken, wenn man in den Dialogfenstern Pfade darauf setzen möchte, aber für eine Vorschau brauchts das nicht.

Na super, gab soeben ein Update von Falllout 4 und noch keine aktuelle Version F4SE dafür. Eigentlich nutzt das bisher nur Place Everywhere. Aber ich baue garantiert nicht ohne das, das verleiht dem Bauen überhaupt erst Sinn. Und eigntlich war ja mein Plan, Taffington Boathouse auszubauen.

[RazorX]

Hast recht, ist schon lange her, man braucht nicht entpacken. Das betraf nur neu erstellte Chars mit eigenen Dateien/Archiven.
Allerdings funzen Preview/Idles so gut wie immer und Fehler oder gar fehlerhafte/keine Anzeigen kann ich da nicht feststellen, selbst wenn man PV voll aufzieht.

[Boïndil]

In dem Fenster springt bei mir alles wild rum, allerdings wären darin sowieso nur die Default-Animationen zu sehen soweit ich weiss, laufen, rennen zielen, hauen, usw.
Im Fenster mit den Idles, wo man normalerweise jeden Actor aufrufen und ihm Idle-Animationen zuweisen kann, kann ich hingegen nicht mal den Actor sehen, den ich gewählt habe.

[Boïndil]

Würde mal behaupten, das ist eine geile und nützliche Funktion: Eine Lampe, die zum Spieler gebeamt wird, wenn er in einer Szene oder Dialog ist. Man kann unter sieben verschiedenfarbigen Lichtern wählen, von kalt-blau über grünlich bis gold, alle werfen Scahtten. Jetzt möchte man nur noch im Dunkeln quatschen In der Szene im Screenshot würde man rein gar nichts sehen, abhängig natürlich auch vom Bildschirm. Und meiner ist dunkler eingestellt, als es die Screenshots zeigen.
Gibt sogar eine nette Preview-Funktion, während man die Lampen konfiguriert, die sollte man an einem dunklen Ort austesten, am Tsg sieht man das kaum.
Wird auf jeden Fall Zeit für einen offiziellen Release von The Wanderer-Effects. Ich habe leider kaum Zeit, es unter allen Aspekten zu testen, aber ich denke, dass es durchaus eine anständige Beta ist, die auf jeden Fall nix kaputt macht. Könnte sein, dass ich morgen dazu komme, spätestens aber am Wochenende.

[Anonymus]

Gibt es eigendlich schon eine Mod mit besseren Geschütztürmen? War letzt im geheimen Biolabor im Institut um Virgils Serum zu holen, da klebten ein paar üble Gatling Lasertürme an den Decken. Ich hatte ne Armeeuniform mit MK5 Fasern verstärkt und ne Marine Rüstung aus Far Harbor, war Level 60, aber die Türme haben mich ziemlich schnell weggeputzt!

Sowas will ich auch haben!

[Boïndil]

Wie wäre es mit Moar Turrets? Nutze ich schon lange, das hat Granatwerfer, Sniper, Cryo, Railway, Kanone, Gauss, Gamma und verschiedene Laser.

So, ich mache jetzt nochmals einen Anlauf, um endlich The Wanderer-Effects online zu bringen. Das wurde in der letzten Zeit arg durch Bethesda verzögert, die es irgendwie fertig brachten, meine Installation mehrmals zu schrotten. Da konnte es am Abend problemlos laufen, und am nächten Tag hatte ich plötzlich fünf Minuten lange Ladezeiten, Slideshows, üble Ruckler und sogar so harte Crashs, dass sich der PC nur noch am Schalter abschiessen liess. Und das ohne Mod- oder Ini-Änderungen. Ja, ja, man soll zuerst die Probleme bei sich suchen, aber wir sprechen hier immerhin von einer Firma, die für deren Qualitätsbewusstsein und technisches Können berüchtigt ist. Und ich modde auch nicht erst seit gestern. Gestern lief es dann plötzlich wieder einigermassen, weiss der Teufel wieso.
Muss nochmals einen letzten Test-Lauf machen, nochmals alle Menus testen und einige Screensots erzeugen, dann sollte er bereit sein.

Scrap Dead Things update ich auch gleich noch und behebe einige Macken. In dieser Version wird man immerhin keine lebenden Feinde mehr scrappen können und alle Asche- und Schleimhaufen werden automatisch beim Zellenreset entsorgt, sofern man sie nicht vorher gescrapt hat. Das betrifft natülich auch Haufen ausserhalb von Siedlungen, die die Landschaft verschandeln. Zur Erläuterung, bei einem Crit-Effekt mit gewissen Waffen wird der Gegner in einen Aschehaufen verwandelt, der sehr flach ist und deshalb bei Bodenwellen sichtbar in der Luft schwebt. Wieso haben die dem nicht einfach mehr Tiefe gegeben, eine Frage, die ich mir schon in Fallout 3 stellte.

Den Fast Travel-Block habe ich auch soben deaktiviert. Ich möchte möglichst auf Schnellreisen verzichten und werde es auch weiterhin tun. Aber heute habe ich einfach keine Zeit mehr, um allzuviele redundante Spaziergänge zu mschen, die manchmal ganz schön nervig sein können, wenn ich hungrig und durstig von jedem straasenköter platt gemacht werden kann, während es in Innenstädten lagt und ruckelt. Abegsehen davon, dass ich als Modder ab und zu einfach Sprünge machen muss, um Dinge zu testen.

[Boïndil]

Scrap Dead Things 1.70 ist online
Alle Aschehaufen und Robottrümmer haben nun ein Script drauf, das sie beim Zellenreset entsorgt, sofern sie nicht vorher gescrapt wurden. Das Script selbst ist in Vanilla enthalten, ich habe es nur angehängt.
Habe einen Combat-Check auf den Spieler in die Scrap-Rezepte eingebaut. So sollte er keine lebende Feinde scrappen können, etwa auf Spectacle Island, wo man sich damit gehörig das Leben erleichtern könnte.
Es gibt nun ein File mit Automatron-Support, was eigentlich nur die Robots im Lair betrifft.

Muss es zwar sagen, soweit ich weiss, werden die Robots im Lair automatisch aufgeräumt. Eigentlich widerspricht ein Automatron-Support deswegen meiner Philosophie.
Scrap Dead Things ist kein Leichenverwertungsmod, sondern ein Bugfix für Mängel im Level-Design, wie etwa nicht auräumbare Skelette in meinem Schlafzimmer oder Ghule, die in Croup Manor das ganze Spiel über von der Decke hängen. Mirelurks habe ich etwa in meinen Listen, weil ich zum einen nicht zwischen permanentem und temporärem Actor unterscheiden kann, zum anderen weil sie wirklich gross sind und nerven. Raider etwa habe ich ausgelassen, weil sie alle nach meinem Wissen automatisch aufgeräumt werden.

Mal sehen, ob ich heute auch noch The Wanderer-Effects raufladen kann. Man unterschätzt aber gerne den Aufwand, einen Mod sauber online zu bringen. Es braucht eine Read Me, Bilder, einen guten Text, Aufräumarbeiten in den Files, das Packen der Daten, usw.